mirror of
https://github.com/mapbase-source/source-sdk-2013.git
synced 2025-03-12 05:30:21 +03:00
7309a5f13f
This should include the latest version of every shader that was in the 2007 SDK. It also includes a smattering of debug shaders, both VR distortion shaders, and other assorted shaders that will hopefully be useful. None of these new files are included in the game shader DLL project. If you need to modify one of these shaders for use in your mod you will need to rename it so that you don't collide with the version of that shader that lives in stdshader_dx9.dll.
40 lines
1.0 KiB
Plaintext
40 lines
1.0 KiB
Plaintext
ps.1.4
|
|
|
|
; Get the 3-vector from the normal map
|
|
texld r0, t0
|
|
; Get environment matrix
|
|
texcrd r1.rgb, t1
|
|
texcrd r2.rgb, t2
|
|
texcrd r3.rgb, t3
|
|
; Normalize eye-ray vector through normalizer cube map
|
|
texld r4, t4 ; <---- CUBE MAP here!!!
|
|
|
|
; Transform normal
|
|
dp3 r5.r, r1, r0_bx2
|
|
dp3 r5.g, r2, r0_bx2
|
|
dp3 r5.b, r3, r0_bx2
|
|
; Reflection calculatiom
|
|
dp3_x2 r3.rgb, r5, r4_bx2 ; 2(N.Eye)
|
|
mul r3.rgb, r5, r3 ; 2N(N.Eye)
|
|
dp3 r2.rgb, r5, r5 ; N.N
|
|
mad r2.rgb, -r4_bx2, r2, r3 ; 2N(N.Eye) - Eye(N.N)
|
|
|
|
phase
|
|
|
|
; Sample environment map
|
|
texld r3, r2
|
|
texld r4, t5 ; Normalize the tangent-space eye vector
|
|
|
|
; dot eye-vector with per-pixel normal from r0
|
|
dp3_sat r1, r4_bx2, r0_bx2
|
|
|
|
; run Fresnel approx. on it: R0 + (1-R0) (1-cos(q))^5 in alpha channel
|
|
mul r0.a, 1-r1.a, 1-r1.a ; squared
|
|
mul r0.a, r0.a, r0.a ; quartic
|
|
mul_sat r1.a, r0.a, 1-r1.a ; quintic
|
|
|
|
; multiply color by reflecttint
|
|
mul r0.rgb, r3, c1
|
|
+mov_sat r0.a, v0.a
|
|
add_sat r0.a, r1.a, r0.a
|